39

I'm currently using the serve script to serve up directories with Node.js on Windows 7. It works well in the MSYS shell or using sh, as I've put node.exe and the serve script in my ~/bin (which is on my PATH), and typing just "serve" works because of it's Shebang (#!) directive which tells the shell to run it with node.

However, Windows Command Prompt doesn't seem to support normal files without a *.bat or *.exe extension, nor the shebang directive. Are there any registry keys or other hacks that I can get to force this behavior out of the built-in cmd.exe?

I know I could just write up a simple batch file to run it with node, but I was wondering if it could be done in a built-in fasion so I don't have to write a script for every script like this?

Update: Actually, I was thinking, is it possible to write a default handler for all 'files not found' etc. that I could automatically try executing within sh -c?

Thanks.

Adam M-W
  • 3,509
  • 9
  • 49
  • 69
  • Have you considered coming back to update the accepted answer? The one you accepted is incorrect, and you have a very good alternative just below it. – Ben Collins Oct 03 '14 at 18:58

6 Answers6

55

Yes, this is possible using the PATHEXT environment variable. Which is e.g. also used to register .vbs or .wsh scripts to be run "directly".

First you need to extend the PATHEXT variable to contain the extension of that serve script (in the following I assume that extension is .foo as I don't know Node.js)

The default values are something like this:

PATHEXT=.COM;.EXE;.BAT;.CMD;.VBS;.VBE;.JS;.JSE;.WSF;.WSH;.MSC

You need to change it (through the Control Panel) to look like this:

PATHEXT=.COM;.EXE;.BAT;.CMD;.VBS;.VBE;.JS;.JSE;.WSF;.WSH;.MSC;.FOO

Using the control panel (Control Panel -> System -> Advanced System Settings -> Environment Variables is necessary to persist the value of the PATHEXT variable.

Then you need to register the correct "interpreter" with that extension using the commands FTYPE and ASSOC:

ASSOC .foo=FooScript
FTYPE FooScript=foorunner.exe %1 %*

(The above example is shamelessly taken from the help provided by ftype /?.)

ASSOC and FTYPE will write directly into the registry, so you will need an administrative account to run them.

Peter Mortensen
  • 30,738
  • 21
  • 105
  • 131
  • 10
    That's not the same as a shebang. A shebang works for **any** file; this only works for particular file extensions. Completely different concept. – user541686 Jul 25 '11 at 15:18
  • 14
    But it will allow the user to run the file without any further ado. –  Jul 25 '11 at 15:19
  • 5
    @Mehrdad this is basically the "Windows equivalent" of shebang. – James Nov 18 '11 at 13:21
  • Quicker PATHEXT setting from elevated command-line: `setx PATHEXT "%PATHEXT%;.FOO" -m` – Svish Feb 05 '13 at 09:39
  • 1
    I learned a lot from this post. It reminds me of this batch script I wrote that associates .jar files with java.exe : https://gist.github.com/djangofan/4144970 – djangofan Apr 09 '13 at 21:52
  • 2
    While this works perfect it drives the shebang line within the files ad absurdum - maybe, under windows, it is better to forget about the use of shebang altogether and work (as described above) completely with custom file extensions instead ?! (That is my lesson learned at least) – petermeissner Jan 30 '15 at 11:51
  • 1
    @petermeissner: Windows does not support a shebang line at all. This is the closest you can get in Windows. The result is the same: you can run a script file without specifying the interpreter. –  Jan 30 '15 at 11:54
  • I suspected that much - thanks for the making this point clear once more. – petermeissner Jan 30 '15 at 12:20
4

Command prompt does not support shebang , however there are a lot hybrid techniques for different languages that you allow to combine batch and other languages syntax in one file.As your question concerns node.js here's a batch-node.js hybrid (save it with .bat or .cmd extension):

0</* :{
        @echo off
        node %~f0 %*
        exit /b %errorlevel%
:} */0;


console.log(" ---Self called node.js script--- ");

console.log('Press any key to exit');
process.stdin.setRawMode(true);
process.stdin.resume();
process.stdin.on('data', process.exit.bind(process, 0));

It is possible to be done with many other languages like Ruby,Perl,Python,PHP and etc.

npocmaka
  • 55,367
  • 18
  • 148
  • 187
  • 1
    Wow! That really works well. The best solution IMO as it requires no changes to the system and works for all interpreters. – marlar Nov 03 '20 at 08:16
  • That is a clever hack. Do you have a reference/link for how this can be done for other languages? In particular, I have been trying to get the equivalent for Python, but I have not been able to avoid cmd printing one line before it restarts the script in the python interpreter (my closest so far: `rem="""\n@python.exe %~f0 %* & @exit /b %errorlevel%\n"""; del rem\n` Cmd prints the first line: rem=""") – sdenham Oct 03 '21 at 17:19
  • 1
    @sdenham - check this -> https://stackoverflow.com/a/41642050/388389 – npocmaka Oct 03 '21 at 21:23
  • 1
    Thanks! You have saved me from being nerd-swiped by this question for much longer than I can afford. – sdenham Oct 04 '21 at 12:14
  • The association workaround (assoc, ftype) is nice for shell environments but this works in Windows API CreateProcess. – bvanlew Aug 10 '22 at 15:05
  • You can see comment symbols – Joao-3 Feb 02 '23 at 17:18
1

Here is a simple way to force windows to support shebang however it has a caveat regarding the file naming. Copy the following text in to a batch file and follow general idea in REM comments.

@echo off

REM This batch file adds a cheesy shebang support for windows
REM Caveat is that you must use a specific extension for your script files and associate that extension in Windows with this batch program.
REM Suggested extension is .wss (Windows Shebang Script)
REM One method to still easily determine script type visually is to use double extensions.  e.g.  script.pl.wss

setlocal enableextensions disabledelayedexpansion
if [%1] == [] goto usage

for /f "usebackq delims=" %%a IN (%1) do (
  set shebang=%%a
  goto decode_shebang
)

:decode_shebang
set parser=%shebang:~2%
if NOT "#!%parser%" == "%shebang%" goto not_shebang

:execute_script
"%parser%" %*
set exit_stat=%errorlevel%
echo script return status: %exit_stat%
goto finale

:not_shebang
echo ERROR script first line %shebang% is not a valid shebang
echo       maybe %1 is not a shebanged script
goto finale

:usage
echo usage: %0 'script with #! shebang' [scripts args]+
echo        This batch file will inspect the shebang and extract the
echo        script parser/interpreter which it will call to run the script

:finale
pause
exit /B %exit_stat%
Doug
  • 199
  • 2
  • 2
0

There's no way to execute random file, unless it is an actual executable binary file. Windows CreateProcess() function just not designed for it. The only files it can execute are those with MZ magic or with extensions from %PATHEXT% list.

However, CMD itself has a limited support for custom interpreters through EXTPROC clause. The limitation is that interpreter should also support and omit this clause in its execution.

AnrDaemon
  • 302
  • 2
  • 9
0

No, there's no way to "force" the command prompt to do this.

Windows simply wasn't designed like Unix/Linux.

Is there a shell extension that does something similar?

Not that I've heard of, but that should be asked on Super User, not here.

Community
  • 1
  • 1
user541686
  • 205,094
  • 128
  • 528
  • 886
0

@npocmaka Thanks for the hint! After some trial and error I found the equivalent for a batch/php hybrid is as follows:

<?/** :
@echo off
C:\tools\php81\php.exe -d short_open_tag=On %~f0 %*
exit /b
*/ ?>
<?php
header('Location: example.com/');
print("<body><h1>Hello PHP!<h1></body>");
?>
bvanlew
  • 1,465
  • 16
  • 13